1. This site uses cookies. By continuing to use this site, you are agreeing to our use of cookies. Learn More.

BDO Launcher for Cerophono's Patcher by YoungKai

Black Desert Online Launcher for Cerophono's Patcher

  1. YoungKai
    ================
    BDO Launcher has been replaced by MR Launcher.
    ================
    This is a script to launch BDO which prompts you with option to launch BDO with or without Cerophono's Patcher (a "nudism mod").

    It automates the manual process of having to rename/move of PAD00001.PAZ file while using Cerophono's Patcher.

    If you use this script as your permanent method of launching BDO, it also protects you from forgetting to revert Cerophono's Patcher, which could results in re-downloading the whole game if BDO scans and finds its file missing.

    Cerophono's Patcher is available at:
    Black Desert Nude Mod

    Installation:
    1. Install Cerophono's Patcher by extracting its files to your game directory.
    2. Create a folder to store backup files.
    3. Copy the Launcher Script below and save it as a ".cmd" file. e.g. "Launch BDO.cmd".
    4. Modify the script by right-clicking and edit the .cmd file
    5. Verify/update BDOPATH and BDObackup variables with the path to your game directory and backup folder (from step 2).

    Code:
    @ECHO OFF
    
    REM Variable list.
    SET BDOPATH="C:\Program Files (x86)\Black Desert Online"
    SET BDObackup="C:\Program Files (x86)\Black Desert Online\Paz-Backup"
    SET EXE=BlackDesert64.exe
    SET LAUNCHER=Black Desert Online Launcher.exe
    REM End of variable list.
    
    REM Begin shortcut creation
    set batchName=%~f0
    set SCRIPT="%TEMP%\%RANDOM%-%RANDOM%-%RANDOM%-%RANDOM%.vbs"
    echo Set oWS = WScript.CreateObject("WScript.Shell") >> %SCRIPT%
    echo sLinkFile = "Launch BDO.lnk" >> %SCRIPT%
    echo Set oLink = oWS.CreateShortcut(sLinkFile) >> %SCRIPT%
    echo oLink.TargetPath = "%batchName%" >> %SCRIPT%
    echo oLink.IconLocation = %BDOPATH:~0,-1%\BlackDesert.ico" >> %SCRIPT%
    echo oLink.Save >> %SCRIPT%
    cscript /nologo %SCRIPT%
    del %SCRIPT%
    REM End of shortcut creation
    
    COLOR 07
    ECHO ^/============================================================================\
    ECHO ^|======================= Black Desert Online Launcher =======================^|
    ECHO ^|========================= for Cerophono's Patcher ==========================^|
    ECHO ^\============================================================================/
    ECHO:
    FOR /F %%i IN ('tasklist /NH /FI "imagename eq %EXE%"') do (SET ImageName=%%i)
    IF "%ImageName%"=="%EXE%" GOTO BDORunning
    IF EXIST %BDOPATH%"\Paz\PAD00001.bak" (
        ECHO PAD00001.bak found.
        ECHO Renaming to PAD00001.PAZ
        RENAME %BDOPATH%"\Paz\PAD00001.bak" PAD00001.PAZ
        ECHO:
    ) ELSE (
        REM File doesn't exist
    )
    IF EXIST %BDOPATH%"\Paz\PAD00001.PAZ" (
        GOTO START
    ) ELSE (
        COLOR CF
        ECHO Missing file PAD00001.PAZ
        ECHO:
        GOTO EOF
    )
    :START
    COLOR E0
    CHOICE /M "Launch BDO with Cerophono's Patcher?"
    IF ERRORLEVEL 2 goto REGULAR
    IF ERRORLEVEL 1 goto PATCH
    :PATCH
    COLOR 07
    ECHO:
    ECHO Opening game launcher...
    ECHO:
    ECHO ===== Press PLAY on game launcher to proceed... =====
    ECHO:
    %BDOPATH%\"%LAUNCHER%"
    FOR /F %%k IN ('tasklist /NH /FI "imagename eq %EXE%"') do (SET ImageName=%%k)
    IF NOT "%ImageName%"=="%EXE%" GOTO NoBDO
    ECHO Backing up file PAD00001.PAZ...
    COPY /Y %BDOPATH%"\Paz\PAD00001.PAZ" %BDObackup%"\PAD00001.PAZ"
    RENAME %BDOPATH%"\Paz\PAD00001.PAZ" PAD00001.bak
    ECHO:
    ECHO Cerophon's Patcher is applied.
    ECHO:
    GOTO EOF
    :REGULAR
    COLOR 07
    ECHO:
    ECHO Opening game launcher...
    ECHO:
    START "Black Desert Online" /D %BDOPATH% "%LAUNCHER%"
    GOTO EOF
    :NoBDO
    COLOR CF
    ECHO:
    ECHO %EXE% was not detected.  Cerophono's Patcher was NOT applied.
    ECHO:
    GOTO EOF
    :BDORunning
    COLOR CF
    ECHO:
    ECHO BDO is already running.
    ECHO:
    :EOF
    ECHO Exiting script.
    TIMEOUT 6
    EXIT

    Using the BDO Launcher Script:
    - Simply use .cmd file to start the game and follow on-screen instructions.
    - Additionally, the script will also create a shortcut file, which you can move or copy to your desktop or Start menu to make it easier to launch the game in the future. Also serves the purpose of a better looking icon than a .cmd file on your Start Menu/Desktop, as well as separating where you are storing a program (script) v.s. a shortcut.
    - Expected usage: Without the BDO game or BDO launcher (the official one) open, run the .cmd file (or the shortcut to the .cmd script). The script will prompt you to choose to run the game with or without Cerophono's Patcher. (See FAQ about always launch with Cerophono's Patcher)
    wh0oot likes this.